#define BUF_SIZE 255

void setup() {
  pinMode(LED_BUILTIN, OUTPUT);
  Serial.begin(9600);
}

char buff[BUF_SIZE];
unsigned int str_pt;
unsigned long int timeout_timer;

void loop() {
  if (Serial.available()) {
    char c = char(Serial.read());
    timeout_timer = millis();//msを取得
    buff[str_pt] = c;
    str_pt++;
    if (c == '\n') {//LFを終端文字とする
      buff[str_pt] = '\0';
      if (strcmp("test\r\n", buff)) {
        //比較文字列と違う
        digitalWrite(LED_BUILTIN, LOW);
        Serial.println("NG");
      } else {
        //比較文字列と同じ
        digitalWrite(LED_BUILTIN, HIGH);
        Serial.println("OK");
      }
      str_pt = 0;
    }
    //バッファサイズを超えなようにする
    if (str_pt >= BUF_SIZE) {
      str_pt = 0;
    }
  } else {
    //データを受信せずに500ms経過した場合にはタイムアウトで初期化
    if (str_pt) {
      if ((millis() - timeout_timer) > 500) {
        str_pt = 0;
      }
    }
  }
}

#include <avr/wdt.h>

#define SYSTEM_TIMEOUT 60  //通信途絶後60秒で初期化
#define BUF_SIZE 255

void setup() {
  wdt_enable(WDTO_4S);  //WDTを４秒で設定し有効化
  //デジタルピン2番から11番まで出力に設定
  for (int i = 2; i < 12; i++) {
    pinMode(i, OUTPUT);
  }
  Serial.begin(9600, SERIAL_8E1);  //偶数パリティ
  serial_wdt_reset();
}

char buff[BUF_SIZE];
char buff_old[BUF_SIZE];

char pin_status[11] = { '0', '0', '0', '0', '0', '0', '0', '0', '0', '0', '\0' };  //デジタルピン2番から11番の状態を保持し一度に転送
unsigned int str_pt;
unsigned long int timeout_timer;

//ピンの状態をまとめて転送
void trans_pin_status() {
  int j = 0;
  for (int i = 2; i < 12; i++) {
    if (pin_status[j] == '1') {
      digitalWrite(i, LOW);  //出力先がアクティブローのため反転
    } else {
      digitalWrite(i, HIGH);
    }
    j++;
  }
}

//ピンに転送前の元データを初期化する
void reset_pin_status() {
  for (int i = 0; i < 10; i++) {
    pin_status[i] = '0';
  }
  pin_status[10] = '\0';
}

unsigned long serial_wdt_counter;
//シリアル通信がSYSTEM_TIMEOUT秒停止した場合に出力をリセットする
void serial_wdt() {
  unsigned long pos = ((unsigned long)millis()) - serial_wdt_counter;
  if (pos > ((unsigned long)((unsigned long)SYSTEM_TIMEOUT * 1000))) {
    reset_pin_status();  //タイムアウトしているため初期化
  }
}

//リセットタイマーをリセットする
void serial_wdt_reset() {
  serial_wdt_counter = millis();
}

void loop() {
  wdt_reset();  //WDTのリセット
  serial_wdt();
  if (Serial.available()) {
    char c = char(Serial.read());
    timeout_timer = millis();  //msを取得
    buff[str_pt] = c;
    str_pt++;
    if (c == '\n') {  //LFを終端文字とする
      buff[str_pt] = '\0';
      if (strcmp(buff_old, buff)) {
        //比較文字列と違うため保存
        strcpy(buff_old, buff);
        Serial.println("NG");
      } else {
        //比較文字列と同じため命令を実行
        if (buff[0] == 'w') {
          int j = 0;
          for (int i = 1; i <= 10; i++) {
            if (buff[i] == '1') {
              pin_status[j] = '1';
            } else {
              pin_status[j] = '0';
            }
            j++;
          }
          Serial.println("OK");
          serial_wdt_reset();
        } else if (buff[0] == 'r') {
          //２回出力
          Serial.print("r,");
          Serial.println(pin_status);
          Serial.print("r,");
          Serial.println(pin_status);
          serial_wdt_reset();
        } else if (buff[0] == 'a') {
          static unsigned long c;
          int _ar[6];
          _ar[0] = analogRead(A0);
          _ar[1] = analogRead(A1);
          _ar[2] = analogRead(A2);
          _ar[3] = analogRead(A3);
          _ar[4] = analogRead(A4);
          _ar[5] = analogRead(A5);

          Serial.print("a,");
          for (int i = 0; i < 6; i++) {
            Serial.print(_ar[i]);
            Serial.print(',');
          }
          Serial.println(c);
          Serial.print("a,");
          for (int i = 0; i < 6; i++) {
            Serial.print(_ar[i]);
            Serial.print(',');
          }
          Serial.println(c++);
          serial_wdt_reset();
        } else if (buff[0] == 't') {
          Serial.println("NG");
        }
        buff_old[0] = '\0';  //命令が終了したため旧命令は破棄
      }
      str_pt = 0;
    }
    //バッファサイズを超えないようにする
    if (str_pt >= BUF_SIZE) {
      str_pt = 0;
    }
  } else {
    //データを受信せずに500ms経過した場合にはタイムアウトで初期化
    if (str_pt) {
      if ((millis() - timeout_timer) > 500) {
        str_pt = 0;
      }
    }
  }
  trans_pin_status();
}